<?xml version="1.0" encoding="utf-8"?>
<images>
<img src="imgs/sidebar.png" />
<img src="imgs/tatt.jpg" />
<img src="imgs/supes.jpg" />
</images>

package {
	import flash.display.Sprite;
	import flash.display.Loader;
	import fl.transitions.Tween;
	import fl.transitions.easing.*;
	import fl.transitions.TweenEvent;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.utils.Timer;
	import flash.events.TimerEvent;
	import flash.net.URLLoader;
	import flash.net.URLRequest;
	import flash.xml.XMLDocument;
	import flash.net.navigateToURL;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.utils.Dictionary;
	public class slideShow extends Sprite {
		var count:Number = new Number(0);
		var imgList:XMLList = new XMLList();
		var paramList:Object;
		var xmlPath:String = "../xml/sidebar.xml";
		var seconds:uint = 1000;
		//Storing the tween globally temporarily prevents it from being dumped prematurely.
		//Fix From: http://www.scottgmorgan.com/blog/index.php/2007/11/18/as3-garbage-collection-the-reason-your-tweens-are-ending-early/
		var antiGC:Dictionary = new Dictionary(false);
 
		public function slideShow():void {
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;
 
 
			var xmlLoader:URLLoader = new URLLoader();
			paramList = this.root.loaderInfo.parameters;
			if (paramList["xmlPath"] != undefined) {
				xmlPath = paramList["xmlPath"];
				seconds = paramList["delay"];
			}
			var xmlURL:URLRequest = new URLRequest(xmlPath);
			xmlLoader.addEventListener(Event.COMPLETE, intSlideShow, false, 0, true);
			intLoading();
			function intLoading() {
				xmlLoader.load(xmlURL);
			}
		}
		public function intSlideShow(evt:Event):void {
			evt.target.removeEventListener(Event.COMPLETE, intSlideShow);
			var xmlDoc:XML = new XML(evt.target.data);
			imgList = xmlDoc.children();
			loadImage();
		}
		public function loadImage():void {
			var imgLoader:Loader = new Loader();
			var imgURL:URLRequest = new URLRequest(imgList[count].@src);
			imgLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, displayObject);
			imgLoader.load(imgURL);
			count++;
			if (count>imgList.length()-1) {
				count=0;
			}
		}
		public function displayObject(evt:Event):void {
			evt.target.removeEventListener(Event.COMPLETE, displayObject);
			var slide:Sprite = new Sprite();
			slide.addChild(evt.target.content);
			slide.addEventListener(Event.ADDED_TO_STAGE, addedToStage);
			stage.addChild(slide);
		}
		public function addedToStage(evt:Event) {
			var animate:Tween = new Tween(evt.target, "alpha", None.easeNone, 0, 1, .4, true);
			animate.addEventListener(TweenEvent.MOTION_FINISH, finishedTween);
			antiGC[animate] = animate;
		}
		public function finishedTween(evt:TweenEvent) {
			antiGC[evt.currentTarget] = null;
			delete antiGC[evt.currentTarget];
			var delay:Timer = new Timer(seconds, 1);
			delay.addEventListener(TimerEvent.TIMER_COMPLETE, hideObject);
			delay.start();
			if (stage.numChildren-1>1) {
				stage.removeChildAt(1);
			}
		}
		public function hideObject(evt:Event):void {
			loadImage();
		}
	}
}